Is this what you want?


  #include "colors.inc"
  #include "finish.inc"

  #declare boxh = 1;
  #declare boxw = 10;
  #declare boxl = 8;

  #declare Mybox =

  box{
   <-boxw/2,0,-boxl/2>
   <boxw/2,boxh,boxl/2>
   texture{
    pigment {Firebrick}
    finish {Shiny}
    }
  }

  camera {
          location 2.5*<0,8,-20>
          look_at <0,0,0>

  }


#declare BrickLength = 10;
#declare BricksInArch = 7;

#declare BrickAngle = 180/BricksInArch;
#declare ArchRadiusB = pow(pow(BrickLength,2)/(2*(1-cos(radians
(BrickAngle)))),.5);
#declare ArchRadius =
pow((pow(BrickLength,2)*(1+cos(radians(BrickAngle))))/(4*(1-cos(radians(BrickAngle)))),.5);

#macro R (Offset,Rotate)
        rotate -90*z translate Offset*x rotate Rotate*z
#end
#macro R2 (Block,NumBlocks,Angle,Radius)
         #local N = 0;
         #while (N<NumBlocks)
           object {Block R(Radius,Angle*N+Angle/2)}
           #local N = N + 1;
         #end
#end

R2 (Mybox,BricksInArch,BrickAngle,ArchRadius)

  light_source {<10,6,-100> rgb 2}


--
Dan Johnson

http://www.geocities.com/zapob

Post a reply to this message

Attachments:
Download 'brickarch.gif' (7 KB)

Preview of image 'brickarch.gif'